Wikiprojekti:Wiki Loves Monuments/SPARQL-kyselyitä

Botin kohteet hakeva kysely

#PREFIX psv: <http://www.wikidata.org/prop/statement/value/>

SELECT DISTINCT 
  ?item 
  (SUBSTR(STR(?item), 32, 250) AS ?wd) ?itemLabel 
  ?rky 
  ?rkyid 
  ((ROUND(?lat * 100000)) / 100000 AS ?lat) 
  ((ROUND(?long * 100000)) / 100000 AS ?long) 
  ?mjid 
  ?rapeaid 
  ?rapea_building_id 
  ?p361_rkyid 
  ?part_of 
  ?p31_instance_of 
  ?p170_creator 
  ?p84_architect 
  ?p466_occupant 
  ?p1435_heritage_designation 
  ?p757_world_heritage_site_id 
  ?p276_location 
  ?p206_on_shore_of 
  ?p706_location_terrain 
  ?p795_on_linear_feature
  ?p131_adm_location
  ?p18_photo
  ?item_list
  (year(?p571_inception) as ?p571_inception)
  WHERE {
  {
  {
    SELECT DISTINCT ?item WHERE {
      {
        ?item wdt:P361 ?rky.
        ?rky wdt:P4009 ?p361_rkyid.
      }
      UNION
      { ?item wdt:P4009 ?rkyid. }
      UNION
      { ?item wdt:P5310 ?rapeaid. }
      UNION
      {
        ?item wdt:P361 ?rky.
        ?rky wdt:P5310 ?p361_rapeaid.
      }
      UNION
      { ?item wdt:P5313 ?rapea_building_id. }
      UNION
      { ?item wdt:P4106 ?mjid. }
      UNION
      {
        ?item wdt:P361 ?rky.
        ?rky wdt:P4106 ?p361_mjid.
      }
     ?item wdt:P131* wd:Q984861.
    }
  }
  OPTIONAL { ?item wdt:P18 ?p18_photo }
  OPTIONAL { ?item wdt:P31 ?p31_instance_of }
  OPTIONAL { ?item wdt:P170 ?p170_creator }
  OPTIONAL { ?item wdt:P84 ?p84_architect  }
  OPTIONAL { ?item wdt:P466 ?p466_occupant }
  OPTIONAL { ?item wdt:P1435 ?p1435_heritage_designation }
  OPTIONAL { ?item wdt:P757 ?p757_world_heritage_site_id }  
  OPTIONAL { ?item wdt:P276 ?p276_location }    
  OPTIONAL { ?item wdt:P206 ?p206_on_shore_of }
  OPTIONAL { ?item wdt:P706 ?p706_location_terrain }  
  OPTIONAL { ?item wdt:P795 ?p795_on_linear_feature }
  OPTIONAL { ?item wdt:P131 ?p131_adm_location }    
  OPTIONAL { ?item wdt:P571 ?p571_inception }
  OPTIONAL { ?item wdt:P361 ?part_of. }
  OPTIONAL { ?item wdt:P4009 ?rkyid. }
  OPTIONAL { ?item wdt:P5310 ?rapeaid. }
  OPTIONAL { ?item wdt:P5313 ?rapea_building_id. }
  OPTIONAL { ?item wdt:P4106 ?mjid. }
  OPTIONAL {
    ?item p:P625 ?coords.
    ?coords psv:P625 ?coordinate_node.
    ?coordinate_node wikibase:geoLatitude ?lat.
    ?coordinate_node wikibase:geoLongitude ?long.
  }
  OPTIONAL { ?item wdt:P170 ?luoja. }
  OPTIONAL { ?item wdt:P84 ?arkkitehti. }
  OPTIONAL { ?item wdt:P5008 ?item_list   }    
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fi". }
}
  FILTER (((!bound(?item_list)) OR (?item_list != wd:Q66713059))) 
  FILTER (((!bound(?p31_instance_of)) OR (?item_list != wd:Q2381508))) 
    
  
}
GROUP BY ?item ?wd ?itemLabel ?rky ?rkyid ?rapeaid ?lat ?long ?mjid ?item_list ?rapea_building_id ?p361_rkyid ?part_of ?p31_instance_of ?p170_creator ?p84_architect ?p466_occupant ?p1435_heritage_designation ?p757_world_heritage_site_id  ?p276_location  ?p206_on_shore_of  ?p706_location_terrain  ?p795_on_linear_feature ?p131_adm_location ?p571_inception ?p18_photo
ORDER BY ?itemLabel ?mjid ?rkyid ?rky ?rapeaid ?rapea_building_id

Kokeile

Maailmanperintökohteiden ja Rky-kohteiden alakohteet

Kysely hakee ne wikipediasivut jotka sijaitsevat Wikidata kohteissa valtakunnallisesti merkittävä rakennettu kulttuuriympäristö (Q29966257) tai maailmanperintöluettelo (Q9259) tai ovat näiden osia.

SELECT ?rky ?rkyLabel ?item ?itemLabel ?coord WHERE {
  VALUES ?allowed_rky_types {wd:Q29966257 wd:Q9259 } .   
  ?rky wdt:P1435 ?allwed_rky_types .
  ?rky wdt:P17 wd:Q33 .
  ?item wdt:P131/wdt:P279*|wdt:P276/wdt:P279*|wdt:P361/wdt:P279* ?rky.  
  OPTIONAL { ?item wdt:P625 ?coord }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fi,sv,en". }
}
GROUP BY ?rky ?rkyLabel ?item ?itemLabel ?coord

Kokeile

Versio 2

SELECT ?rky ?rkyLabel ?country ?item ?itemLabel ?lat ?long WHERE {
  VALUES ?allowed_rky_types {wd:Q29966257 wd:Q9259  wd:Q31027091} .   
  ?rky wdt:P1435 ?allowed_rky_types .
  ?item wdt:P276* ?rky .
  ?rky wdt:P131* wd:Q33 .
  OPTIONAL {?rky wdt:P17 ?country }
  OPTIONAL { ?item p:P625 ?coords . ?coords psv:P625 ?coordinate_node . ?coordinate_node wikibase:geoLatitude ?lat . ?coordinate_node wikibase:geoLongitude ?long . }  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fi,sv,en". }
}
GROUP BY ?rky ?rkyLabel ?item ?itemLabel ?lat ?long ?country

Kokeile